移動平均線クロスを知らせてくれるインジケーター

//+------------------------------------------------------------------+
//|                                                MA_CrossAlert.mq4 |
//|                                            iNak Engineering, LLC |
//|                                             https://inak-eng.jp/ |
//+------------------------------------------------------------------+
#property copyright "iNak Engineering, LLC"
#property link      "https://inak-eng.jp/"
#property version   "1.00"
#property strict

#property indicator_chart_window
#property indicator_buffers 4
#property indicator_color1 Yellow
#property indicator_color2 Cyan
#property indicator_color3 Red
#property indicator_color4 Blue

#property indicator_style1 STYLE_SOLID
#property indicator_style2 STYLE_SOLID
#property indicator_width1 2
#property indicator_width2 2
#property indicator_width3 5
#property indicator_width4 5

double Buf_MA_1[];
double Buf_MA_2[];
double Buf_GC[];
double Buf_DC[];

extern int MA_1_Mode = 0;    //Short Term MA Mode
extern int MA_1_Period = 25; //Short Term MA Period
extern int MA_1_Price = 0;   //Short Term MA Price
extern int MA_2_Mode = 0;    //Long Term MA Mode
extern int MA_2_Period = 50; //Long Term MA Period
extern int MA_2_Price = 0;   //Long Term MA Price

int nowbar;

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   SetIndexBuffer(0,Buf_MA_1);
   SetIndexBuffer(1,Buf_MA_2);
   SetIndexBuffer(2,Buf_GC);
   SetIndexBuffer(3,Buf_DC);

   SetIndexStyle(2,DRAW_ARROW,STYLE_SOLID);
   SetIndexArrow(2,233);

   SetIndexStyle(3,DRAW_ARROW,STYLE_SOLID);
   SetIndexArrow(3,234);

   nowbar = Bars;

   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---

//---
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
int OnCalculate(
   const int rates_total,
   const int prev_calculated,
   const datetime &time[],
   const double &open[],
   const double &high[],
   const double &low[],
   const double &close[],
   const long &tick_volume[],
   const long &volume[],
   const int &spread[]
)
  {
   int counted_bar = IndicatorCounted();
   int limit = Bars-counted_bar;

   if(counted_bar == 0)
      limit -= MA_2_Period-1;
   for(int i=limit-1; i>=0; i--)
     {
      Buf_MA_1[i] = iMA(NULL,0,MA_1_Period,0,MA_1_Mode,MA_1_Price,i);
      Buf_MA_2[i] = iMA(NULL,0,MA_2_Period,0,MA_2_Mode,MA_2_Price,i);
     }

   if(counted_bar == 0)
      limit -= 2;
   for(int i=limit-1; i>=0; i--)
     {
      Buf_GC[i] = EMPTY_VALUE;
      if(Buf_MA_1[i+2] <= Buf_MA_2[i+2] && Buf_MA_1[i+1] > Buf_MA_2[i+1])
        {
         Buf_GC[i+1] = Low[i+1]-30*Point;
         if(nowbar != Bars && i == 0)
           {
            Alert(Symbol(),", Golden Cross");
            nowbar = Bars;
           }
        }
      Buf_DC[i] = EMPTY_VALUE;
      if(Buf_MA_1[i+2] >= Buf_MA_2[i+2] && Buf_MA_1[i+1] < Buf_MA_2[i+1])
        {
         Buf_DC[i+1] = High[i+1]+30*Point;
         if(nowbar != Bars && i == 0)
           {
            Alert(Symbol(),", Dead Cross");
            nowbar = Bars;
           }
        }
     }
   return(rates_total);
  }
//+------------------------------------------------------------------+